{ pkgs, lib, inputs, ... }:

let
  rishot = pkgs.callPackage ../../pkgs/rishot.nix { };
in

# Desktop applications for a workstation host (currently: terra). Split from
# desktop-hyprland.nix, which owns the *session* (compositor, greeter, audio,
# portals); this owns the things the user actually launches inside it.
{
  nixpkgs.config.allowUnfreePredicate = pkg:
    builtins.elem (lib.getName pkg) [
      "gitkraken"
      "jetbrains-toolbox"
      "steam"
      "steam-unwrapped"
      "steam-run"
      "claude-code"
      "vivaldi"
    ];

  programs.steam = {
    enable = true;
    remotePlay.openFirewall = true;
    dedicatedServer.openFirewall = false;
  };
  hardware.graphics.enable32Bit = true;

  environment.systemPackages = with pkgs; [
    alacritty
    zed-editor
    protonplus
    gitkraken
    jetbrains-toolbox
    kdePackages.dolphin
    vivaldi
    rishot
    # tome removed for now — private git+ssh flake input the installer can't
    # fetch. The dev SDKs below stay (public, cached) for when it comes back.

    # Tome development (Tome.App targets net10.0; ClientApp is Preact/Vite).
    dotnetCorePackages.sdk_10_0
    nodejs
  ];

  fonts.packages = [ pkgs.nerd-fonts.departure-mono ];
}