Files
homelab/services/desktop/unreal-engine.nix
T
2026-11-14 15:55:48 +01:00

99 lines
2.0 KiB
Nix

{ pkgs, ... }:
# Unreal Engine: Epic's prebuilt Linux zip in an FHS env. The zip is behind an
# Epic login, so it's unpacked by hand to engineDir rather than fetched by Nix.
let
engineDir = "/mnt/ssd_01/unreal/UE_5.8.4";
fhs = name: runScript: pkgs.buildFHSEnv {
inherit name runScript;
targetPkgs = p: with p; [
# Editor
vulkan-loader
vulkan-tools # vulkaninfo, to debug from unreal-shell
libGL
libxkbcommon
wayland
alsa-lib
libpulseaudio
udev
fontconfig
freetype
zlib
stdenv.cc.cc.lib
libxcrypt-legacy
util-linux.lib
libx11
libxcb
libxcursor
libxext
libxfixes
libxi
libxinerama
libxrandr
libxrender
libxscrnsaver
libxtst
libsm
libice
# CEF (Fab, web browser widgets)
at-spi2-atk
at-spi2-core
atk
cairo
cups
dbus
expat
glib
gtk3
libdrm
libgbm
libxcomposite
libxdamage
nspr
nss
pango
# UnrealBuildTool (bundled .NET) and C++ project builds
icu
krb5
openssl
bash
coreutils
file
findutils
gawk
git
gnugrep
gnumake
gnused
rsync
which
xdg-utils
];
# The session exports wayland; the editor's windowing targets X11.
# hyprchrome-claude's LD_LIBRARY_PATH needs a newer glibc than this env's.
profile = ''
export SDL_VIDEODRIVER=x11
unset LD_LIBRARY_PATH
'';
};
editor = fhs "unreal-editor" "${engineDir}/Engine/Binaries/Linux/UnrealEditor";
shell = fhs "unreal-shell" "bash"; # RunUAT, project builds, debugging
desktopItem = pkgs.makeDesktopItem {
name = "unreal-editor";
desktopName = "Unreal Editor";
exec = "unreal-editor %F";
categories = [ "Development" "IDE" ];
startupWMClass = "UnrealEditor";
};
in
{
environment.systemPackages = [ editor shell desktopItem ];
systemd.tmpfiles.rules = [ "d /mnt/ssd_01/unreal 0755 darman users -" ];
}